7 - UN PROGRAMA EN GBASIC

7-d. Resolución del Sistema.

A partir de la línea tres mil comienza la tarea de estimar la evolución de la distribución porcentual de las estrategias, proceso que se repetirá seiscientas veces.

3000 FOR S = 1 TO 5
3010 E = 0

Para cada una de las estrategias, el valor del juego se inicializa a cero.

3020 FOR Z = 1 TO 5
3030 E = E + M (S, Z) *P(Z)
3040 NEXT

M(S,Z) es el pago que recibe una empresa de estrategia S en un conflicto con otra de estrategia Z. La probabilidad de un conflicto con Z es P(Z). En cualquier momento el beneficio esperado para cualquier empresa S como consecuencia de su enfrentamiento con otra es el sumatorio de M(S, Z) * P(Z) para todo Z, lo que queda estimado mediante las tres líneas anteriores.

3045 T(S) = E

El valor final de E será la tasa de crecimiento' para la estrategia "S".

3050 M = M + T(S) * P(S)/100

Cuando el bucle de S se haya completado, el valor de M será la media ponderada de las tasas de crecimiento.

3060 E(S) = P (S) * (1 + E/I)
3070 NEXT

E(S) es el valor en que habrá que incrementar la proporción de empresas de estrategia S. Naturalmente hay que tener en cuenta P(S) ya que indica la probabilidad de que S entre en conflicto con las demás. Dicho de otra forma, cuanto menor sea el número de empresas con estrategia S o menor sea la proporción de su producción sobre el total, menor será su probabilidad de hacer negocios o de entrar en conflicto con las demás. Obsérvese también en la línea 3060 que el beneficio esperado E queda dividido por el valor  de incidencia I. Dando un valor más bajo a I se puede conseguir que las variaciones de los porcentajes sean más grandes, la evolución de los acontecimientos más rápida, y las curvas aparezcan más comprimidas en sentido horizontal.

Una vez que se ha estimado el valor de E(S) para todas las estrategias, se puede proceder a estimar la nueva distribución de estrategias.

3080 FOR S = 1 TO 5
3090 P(S) = P(S) + E(S)
3110 T = T + P(S)
3120 NEXT
3130 FOR S = 1 TO 5
3140 P(S) = P(S) * 100 / T
3150 NEXT
3160 T = 0

Los resultados obtenidos se presentaran sobre el siguiente  punto del eje de abcisas.

3170 X = X + .25

Conviene recordar aquí que el origen de ordenadas estaba en X = 9 y que cada unidad de X está dividida por cuatro puntos en la pantalla.

3180 IF G$ = "DEC" THEN GOSUB 4000
3185 IF G$ = "EXP" THEN GOSUB 5000
3190 IF G$ = "TAS" THEN GOSUB 6000
3195 IF G$ = "EDE" THEN GOSUB 7000

Tras la presentación en pantalla, tarea encargada a las subrutinas que comienzan en las líneas 4000, 5000, 6000 Y 7000, dejaremos en cero el valor de M para que pueda volverse a estimar en el siguiente proceso.

3200 M = 0
3205 IF X = 159 THEN GOTO 10000
3210 GOTO 3000

Si se han realizado ya los seiscientos procesos, el valor de X seria 159. En ese caso el ordenador pasará a realizar las tareas finales con las órdenes que comienzan en la línea 10000. En caso contrario, volverá a realizar un nuevo proceso a partir de la línea 3000.